#!/system/bin/tcsh -f

#location of the database for samsung android 4.2.2
set db=/data/data/com.android.providers.telephony/databases/mmssms.db
set logdb=/data/data/com.sec.android.provider.logsprovider/databases/logs.db
set misseddb=/data/data/com.sec.android.app.keyguard/databases/MissedEvent.db
set badgedb=/data/data/com.sec.android.provider.badge/databases/badge.db

#echo 'select * from sms;' |sqlite3 $db |\
#list all 
if ( ${#} == 0 ) then
echo "select _id,thread_id,address,person,date,date_sent,protocol,read,status,type,reply_path_present,subject,replace(body,x'0a',' '),service_center,locked,error_code,seen,deletable,hidden,group_id,group_type,delivery_date,app_id,msg_id,callback_number,reserved,pri,teleservice_id,link_url,svc_cmd,svc_cmd_content,roam_pending from sms;" |sqlite3 $db |\
sort -n -t '|' -k 5 |\
gawk -F'|' '{printf("%s|%s|%s|%s|%s\n",$1,$3,$5,$10,$13);}' > /data/tmp/smsr

#look up contacts
cat /dev/null > /data/tmp/smsr2
gawk -F'|' < /data/tmp/smsr > /data/tmp/smsr2 '{system("/system/bin/contact "$2);}'

#merge the two files
gawk </data/tmp/smsr '{printf("%s|",$0); getline <"/data/tmp/smsr2"; print $0;}' > /data/tmp/smsr3

#final output formatting
gawk </data/tmp/smsr3 -F'|' '{printf("%3d. %s %s (%-16s) DATE %-15s TEXT: %s\n",$1,($4==2?"TO  ":"FROM"),$2,$6,strftime("%Y %B %d %H:%M:%S",$3/1000),$5);}'

#mark messages as having been read
echo 'update sms set seen = 1; update sms set read = 1; '  |sqlite3 $db
echo 'update threads set read = 1; update threads set unread_count = 0; '  |sqlite3 $db

#exception for some messages
#gawk '-F|' < /data/tmp/smsr 'NF <=6' |egrep 'Amount:|Code:|Date:|Merchant:'|sed -e 's/|.*|//g' 


rm -f /data/tmp/smsr  /data/tmp/smsr2 /data/tmp/smsr3
exit 0
endif


if ( x"$1" == "xclean" || x"$1" == "xclear"  ) then
echo 'delete from sms;' | sqlite3 $db
echo 'delete from threads;' | sqlite3 $db
exit 0
endif

if ( x"$1" == "xcleanall" || x"$1" == "xclearall"  ) then
echo 'delete from sms; delete from threads;' | sqlite3 $db
echo 'delete from logs;'| sqlite3 $logdb 
echo 'delete from unreadMsgInfo; delete from missedCallInfo;'| sqlite3 $misseddb
echo 'update apps set badgecount = 0 where package == "com.android.mms"; update apps set badgecount = 0 where package == "com.android.contacts";'| sqlite3 $badgedb
#to get the icon update, we need to restart com.sec.android.provider.badge
#I know how to kill it but not how to start it from inside phone command line (standalone 'am' crashes and adb loopback does not work)
#in this way, the count should be updated with next incoming call or sms
#still, removal from notifications should be done somehow...
#killall com.sec.android.provider.badge 
exit 0
endif


echo Unknown command $1
exit 1